Context Free Art!

I've recently discovered the wonderful world of Context Free Art. It's a way of procedurally generating images through a simple programming language.

The thing that drives me about context free art is how it enables me to create incredibly complex images from a few lines of simple code. And it's got a great community where you post your designs for everyone to comment on. Often other programmer artists will give you helpful tips or code variants which make your designs come out in radically different ways.

Below are images of the designs I've uploaded to the context free art community and the designs' respective source code.

"Spatter"

startshape S
background { b 1 }

rule S {
    R {}
    R { r 90 y 2 }
    R { r 180 y 2 }
    R { r 270 y 2 }
}

rule R {
    DOT {}
    R { r 2 s .995 a -.01 }
}

rule R  .01 {
    DOT {}
    R { r 2 s .995 a -.01  }
    R { r 2 s .995 a -.01  f 0 y 2 }
}

rule DOT {
    CIRCLE { s .15 y .02 h 7 sat 0.8873 b 0.5780 }
}

---

"Spongey"

startshape S

rule S {
    R {}
    R {r 120 y 2}
    R {r 240 y 2}
}

rule R {
    dot {}
    R {r 2 s .995 a -.005}
}

rule R .04 {
    dot {}
    R {r 2 s .995 a -.005}
    R {r 2 s .995 a -.005 f 0 y 2}
}

rule R .05 {
    R {r 0 s .995 a -.005 f 0 y 2}
}

rule dot {
    CIRCLE {s .1 y .1 }
}

---

"Hairy"

startshape P

rule P {
    1000* {r 0.36} A {}
}

rule A 6 {
    B {}
    A { y 2 r -3 s 0.9993 }
} 

rule A 5.45 {
    B {}
    A { y 2 r 3 s 0.99999}
}

rule B { 
   SQUARE { y 1 s 7 2 a .5 } 
   SQUARE { x -2.0 s 6 2.2 b .2 a -.5 } 
   SQUARE { x -2.0 s 5 2.4 b .3 a -.5 } 
   SQUARE { x -2.0 s 4 2.6 b .4 a -.5 } 
   SQUARE { x -2.0 s 3 2.8 b .6 a -.5 }
   SQUARE { x -2.0 s 2 3.0 b .8 a -.5 }
   SQUARE { x -2.0 s 1 3.2 b 1 a -.5 }
}

Comments

[Stefan Å]

Hey! This is incredibly cool. You should hook it up with an AI that creates an abstract picture every now and then, at random dates, and then automatically posts it to an online art gallery along with a random title for the image. Then its just a matter of time before the pictures hit guggenheim. The thought of an artificial abstract expressionist is just too cool.